1. Functiesuitgeverijvandebunt.nl/images/downloaden... · Hoofdstuk 2 – Maak een dashboard met...

Hoofdstuk 2 – Maak een dashboard met Excel 2013 Pagina 1

1. Functies

Bij het maken van de grafieken in de volgende hoofdstukken, zult u verschillende

functies moeten gebruiken. Vaak moeten ze ook nog eens worden gecombineerd.

Om te voorkomen dat u de grafieken en de functies tegelijk onder de knie moet

krijgen, eerst een hoofdstuk met uitleg over de gebruikte functies.

1.1. VERTICAAL ZOEKEN (VLOOKUP)

VERT.ZOEKEN is één van de meest gebruikte Excelfuncties. Het is een vrij

eenvoudige functie die gemakkelijk met andere functies kan worden gecombineerd.

Zoals de naam al prijsgeeft is het een zoekfunctie die wordt gebruikt om informatie uit

een tabel of database te halen.

De functie VERT.ZOEKEN zoekt in de meest linkse kolom van een matrix, een

celbereik, naar een opgegeven waarde en geeft als resultaat een waarde uit de

opgegeven kolom.

Om de zoekfunctie te kunnen gebruiken moet de tabel aan twee voorwaarden voldoen;

De eerste kolom moet de informatie bevatten waarmee de informatie uit de tabel

kan worden gehaald.

De tabel moet zijn gesorteerd op de eerste kolom.

De functie heeft 4 argumenten; Zoekwaarde Verplicht De verwijzing geeft aan in welke cel de zoekterm

staat.

Tabelmatrix Verplicht Het bereik van de tabel waarin de gegevens staan.

Kolomindex_getal Verplicht Het nummer van de kolom aan waarin de informatie

wordt gezocht.

Benaderen WAAR Zoekt de best mogelijke waarde in de eerste kolom.

ONWAAR De gevonden waarde moet exact overeenkomen.

Voorbeelden

De voorbeelden staan in de werkmap ‘VERT.ZOEKEN’. U kunt de functie vinden onder de tab ‘Formules’ in de functiebibliotheek onder de knop ‘Zoeken en verwijzen’.


Voorbeeld 1

Maak het werkblad ‘Voorbeeld 1’ actief.

De formule in cel D11 is; =VERT.ZOEKEN(D9;A2:D7;4;ONWAAR)

Zoekwaarde D9

Tabelmatrix A2:D7

Kolomindex_getal 4e kolom

Benaderen ONWAAR De gevonden waarde moet exact overeenkomen.

Wat doet de functie VERT.ZOEKEN?

De functie zoekt in de eerste kolom van de zoektabel naar de zoekwaarde ‘Hacienda’. De functie gaat naar de 4e kolom van de matrix (vanaf de linkerkant) en vindt de waarde 34.700. Geen van de celadressen is absoluut. Dat mag wel, maar is in dit geval niet nodig.

De functie wordt immers niet doorgetrokken.

De argumenten zijn van elkaar gescheiden door punt-komma’s.

Bekijk goed hoe de functie is opgebouwd.

Pas de zoekopdracht in cel D9 aan.

Voorbeeld 2

De formule in B2 is; =VERT.ZOEKEN($A2;$G$2:$K$11;2;0)

Zoekwaarde $A2

Tabelmatrix $G$2:$K$11


Benaderen 0


Zoekwaarde De functie moet worden doorgetrokken naar beneden. De zoekwaarde

bij de volgende rij staat in cel A3. Daarom is in het celadres, $A2, alleen de kolom absoluut.

Tabelmatrix De tabelmatrix, $J$2:$N$11, is volledig absoluut. Dit bereik mag tijdens het doortrekken niet worden aangepast.

Benaderen In plaats van ‘Onwaar’ mag u ook een 0 invoeren. Een 1 staat voor

‘Waar’.

Bekijk de functies in de tabel goed. Voorbeeld 3

De formule in D16 is; =VERT.ZOEKEN(D13;A2:B11;2;1)

Zoekwaarde C13

Tabelmatrix A2:B11


Benaderen WAAR

Zoekwaarde De functie hoeft niet te worden doorgetrokken. Het celadres, C13, hoeft dus niet absoluut te zijn. Dit geldt ook voor de tabelmatrix, A2:B11.

Benaderen In plaats van ‘Waar’ is een 1 gebruikt. Excel zal er automatisch ‘Waar’ van maken.

Wat doet de functie VERT.ZOEKEN?

De functie zoekt in de eerste kolom van de tabel naar de zoekwaarde ‘8,6’. Deze waarde komt niet voor in de kolom. Het argument ‘Benaderen’ geeft ‘WAAR’ aan. Elke waarde tot de waarde in de volgende cel, in dit geval 9,4 wordt behandeld als een 8,5. De functie gaat één kolom naar rechts, en vindt de waarde ‘Goed’.


Voorbeeld 4

De formule in cel B11 is; =VERT.ZOEKEN(A11;$A$2:$G$7;$D$9+1;ONWAAR)

Zoekwaarde A11

Tabelmatrix $A$2:$G$7

Kolomindex_getal D9+1

Benaderen ONWAAR

Zoekwaarde De functie moet worden doorgetrokken, dus relatief. Tabelmatrix De functie moet worden doorgetrokken, de matrix mag daarbij niet

veranderen, dus is absoluut gemaakt. Kolomindex_getal Maand 4 is de maand april. Maar deze waarde staat in kolom 5.

Vandaar de verwijzing; D9 + 1, dus kolom 5. Benaderen De gevonden waarde moet exact overeenkomen.

Door in cel D9 een variabele in te voeren wordt de functie VERT.ZOEKEN dynamisch. U hoeft alleen de waarde in cel D9 te veranderen en er worden gegevens van een andere maand getoond.


1.2. AANTAL.ALS (COUNTIF)

De functie AANTAL.ALS telt hoe vaak één bepaalde waarde voorkomt in een lijst.

Beschrijving De functie AANTAL.ALS telt het aantal cellen (de frequentie) in een bereik dat

voldoet aan een enkel criterium.

Syntaxis

AANTAL.ALS(bereik, criterium)

Bereik Verplicht De matrix waarbinnen wordt geteld. Criterium Verplicht Een woord of getal dat bepaalt welke cellen worden geteld. Voorbeelden

De voorbeelden staan in de werkmap ‘AANTAL.ALS’. U kunt de functie vinden in de functiebibliotheek onder de knop ‘Meer functies’ en

dan ‘Statistisch’.

Open het werkblad ‘AANTAL.ALS’.

U kunt de functies vinden in rij 300 en 301.

Voorbeeld 1

Hoe vaak komt de naam Jongsma voor in het bereik G2:G298?

Syntaxis AANTAL.ALS(bereik, criterium) AANTAL.ALS(G2:G298, Jongsma) Resultaat 84

Wat doet de functie AANTAL.ALS?

De functie zoekt in het bereik G2:G298 naar de tekst “Jongsma” en telt het aantal

resultaten.


Voorbeeld 2

Hoe vaak komen de namen Jongsma en Bouwhuis voor in kolom G.

Syntaxis AANTAL.ALS(bereik, criterium)+ AANTAL.ALS(bereik, criterium) AANTAL.ALS(G2:G298,“Jongsma”)+AANTAL.ALS(G2:G298,”Bouwhuis”) Resultaat 202

Opmerkingen In het eerste voorbeeld was het nog mogelijk de gegevens voor de functie in te

voeren via het functievenster ‘Functieargumenten’. In het tweede voorbeeld is dat

niet meer mogelijk. U zult de functie dus moeten intypen. Dat lijkt veel werk, maar

levert meer begrip van de functie op.

In dit geval is het adres van de tabelmatrix absoluut ingetypt, dat hoeft niet, want de

functie wordt niet doorgetrokken. Aan de andere kant, mogelijk verplaatst u de

functie en kunnen er celadressen gaan verschuiven. Het kan geen kwaad, dus

misschien is het een goede gewoonte om celadressen en celbereiken absoluut in te

typen.

Teksten worden altijd ingetypt met een dubbel aanhalingsteken; “Jongsma”.

1.3. AANTALLEN.ALS (COUNTIFS)

De functie AANTALLEN.ALS telt hoe vaak een bepaalde waarde voorkomt in een

lijst. Daarnaast moet er ook worden voldaan aan minimaal één extra criterium. De

functie AANTALLEN.ALS combineert de argumenten. Alleen de waarden die voldoen

aan alle criteria worden geteld.

Voorbeeld 1

U wilt weten hoe vaak de naam Jongsma voorkomt in de tabel in de maand

december.

Maak het werkblad ‘AANTALLEN.ALS’ actief.

Criterium 1; Hoe vaak komt de naam Jongsma voor in het bereik G2:G298? Criterium 2; Zoek in het bereik C2:C298 naar de waarde december.


Syntaxis AANTALLEN.ALS (Criteriumbereik1, Criterium1; Criteriumbereik2, Criterium2)

AANTALLEN.ALS (G2:G298;"Jongsma";C2:C298;"December") Resultaat 10

Voorbeeld 4

U wilt weten hoe vaak Jongsma voorkomt in de tabel in de maand december bij de

verkoop van ‘El Injerto’.

Criterium 1; Hoe vaak komt Jongsma voor in het bereik G2:G298? Criterium 2; Zoek in het bereik C2:C298 naar de waarde december. Criterium 3; Zoek in het bereik E2:E298 naar de waarde El Injerto.

Syntaxis AANTALLEN.ALS (criteriumbereik1, criterium1, ;criterium_bereik2, criterium2; enz.

AANTALLEN.ALS(G2:G298;"Jongsma"; C2:C298;"December"; E2:E298;"El Injerto")

Resultaat; 3


Opmerkingen

U mag maximaal 127 paren met een bereik en een criterium gebruiken.

U moet de functie dan wel intypen in de formulebalk. (veel succes)

Elk extra bereik moet een deel zijn van het eerste bereik.

De bereiken hoeven niet aan elkaar te grenzen.

Als u teksten rechtstreeks in de formulebalk typt, moet u om de tekst altijd

dubbele aanhalingstekens typen.

De functiefamilie AANTAL

In de functiefamilie AANTAL kunt u nog 3 varianten vinden.

AANTAL Telt het aantal cellen in een bereik dat getallen bevat. AANTAL.LEGE.CELLEN Telt het aantal lege cellen in een bereik. AANTAL.ARG Telt het aantal niet lege cellen in een bereik.


1.4. VERGELIJKEN (MATCH)

De functie VERGELIJKEN geeft als resultaat de positie van een waarde in een

bereik, dat overeenkomt met een opgegeven waarde. Deze functie geeft dus alleen

de plaats van de zoekwaarde binnen het bereik. Het geeft dus niet de waarde zelf.

Het bereik is een kolom of een rij.

De functie VERGELIJKEN zoekt naar een vergelijkbare waarde als de

zoekwaarde in een bepaalde kolom of rij.

De functie VERGELIJKEN heeft op zich zelf niet zoveel nut. Het zoekt een

vergelijkbare waarde als de zoekwaarde en geeft aan waar deze staat. Hij wordt

daarom vooral gebruikt in samenwerking met andere zoekfuncties, zoals INDEX,

VERT.ZOEKEN, HOR.ZOEKEN of VERSCHUIVING.

De functie VERGELIJKEN heeft 3 argumenten. Zoekwaarde Verplicht De waarde die wordt gebruikt om een waarde in de

matrix (bereik) te zoeken. De waarde kan een getal, tekst zijn.

Zoeken_matrix Verplicht Dit is een aaneengesloten celbereik. Criteriumtype_getal Dit is het getal 1, 0 of -1 dat aangeeft welke waarde

het resultaat moet hebben. Criteriumtype_getal 1 De eerste waarde gelijk aan of kleiner dan de

zoekwaarde. De tabel moet dan wel oplopend zijn gesorteerd.

0 De eerste waarde die gelijk is aan de zoekwaarde.

-1 De eerste waarde die gelijk of groter is dan de zoekwaarde. De tabel moet dan wel aflopend zijn gesorteerd.

Voorbeelden

U kunt de functie vinden in de functiebibliotheek onder de knop ‘Zoeken en

verwijzen’.

Open de werkmap ‘VERGELIJKEN’, maak het blad ‘Voorbeeld 1’ actief.


Voorbeeld 1 Hier wordt de functie ‘Vergelijken’ gebruikt om de positie van de waarde als in A1 in het bereik C1:C10 te vinden. Het zoekt de eerste keer dat deze waarde voorkomt in het aangegeven bereik.

De formule in cel E1 is =VERGELIJKEN(A1;C1:C10;0)

Zoekwaarde A1 = 400,00 Zoeken_matrix C1:C10 Criteriumtype_getal 0 De eerste waarde die gelijk is aan de zoekwaarde.

De kolom moet oplopend zijn gesorteerd. Resultaat 5 Het getal 400,00 staat op de 5e positie in het bereik C1:C10. Voorbeeld 2 Zoek naar de positie van een vergelijkbare waarde als in A1 in het bereik C1:C10.

Zoek de eerste keer dat deze waarde voorkomt, of anders de eerste waarde die

kleiner is dan 450,00.


De formule in cel E1 is =VERGELIJKEN(A1;C1:C10;1)

Zoekwaarde A1 = 450,00 Zoeken_matrix C1:C10 Criteriumtype_getal 1 De eerste waarde die gelijk is aan, of kleiner is dan de

zoekwaarde. De kolom moet oplopend zijn gesorteerd.

Resultaat 9 Het getal 450,00 bestaat niet, dus is de eerste kleinere waarde gevonden, 440,00. Deze waarde staat op de 9e positie in het bereik C1:C10.

Voorbeeld 3 Zoek naar de positie van een vergelijkbare waarde als in A1 in het bereik C1:C10.

Zoek de eerste keer dat deze waarde voorkomt, of anders de eerste waarde die

groter is dan 450,00.

De formule in cel E1 is =VERGELIJKEN(A1;C1:C10;-1)

Zoekwaarde A1 = 450,00 Zoeken_matrix C1:C10 Criteriumtype_getal -1 De eerste waarde die gelijk is, of groter is dan de

zoekwaarde. De kolom moet aflopend zijn gesorteerd.

Resultaat 1 Het getal 450,00 bestaat niet, dus is de eerste grotere waarde gevonden, 520,00. Deze waarde staat op de 1e positie in het bereik C1:C10.


1.5. VERT.ZOEKEN en VERGELIJKEN

De functie VERT.ZOEKEN werkt uitstekend, totdat er veranderingen optreden in het bereik, de matrix, waarbinnen de functie moet zoeken. Zodra er kolommen worden ingevoegd of van plaats worden gewisseld, ontstaan er foutmeldingen. Bij het invoeren van de argumenten voor de functie VERT.ZOEKEN wordt een kolom-nummer opgegeven. Als de situatie binnen het opgegeven bereik verandert, zal de formule zich niet aanpassen. Het is een statische functie. In samenwerking met de functie VERGELIJKEN wordt de functie dynamisch. De

functie kan dan reageren op veranderingen in de tabel. In het hoofdstuk over

grafieken zal de term ‘dynamisch’ nog vaak terugkomen.

Open de werkmap ‘VERT.ZOEKEN en VERGELIJKEN’ en open het werkblad

‘Namen’.

Voorbeeld 1

In dit voorbeeld is in cel D2 de functie =VERT.ZOEKEN($A2;$G$2:$K$11;4;0)

gebruikt. Er moet naar de naam van de afdeling worden gezocht.

In de matrix wordt een extra kolom ingevoerd, Woonplaats. Daardoor wordt kolom D gevuld met de gegevens van de nieuwe kolom, Woonplaats. Kolom E wordt nu gevuld met de gegevens van ‘Afdeling’.

De fout wordt veroorzaakt door de functie VERT.ZOEKEN. Dit is een statische

functie, wat wil zeggen dat de functie zich niet aanpast aan een nieuwe situatie. Het

argument Kolomindex_getal is de boosdoener. Het blijft verwijzen naar kolom 4.

Door de functie VERT.ZOEKEN te combineren met de functie VERGELIJKEN kan dit

probleem worden opgelost en wordt de functie VERT.ZOEKEN dynamisch.

De functie VERGELIJKEN geeft als resultaat de positie van een waarde in een

bereik, dat overeenkomt met een opgegeven waarde. Deze functie geeft dus de

plaats van de zoekwaarde binnen het zoekbereik. Het geeft dus niet de waarde zelf.

Dat is precies wat het argument Kolomindex_getal nodig heeft. Een functie die de

locatie van een bepaalde kolom opzoekt.


De functie samenstellen U moet deze functie met de hand intypen om te begrijpen wat er gebeurt. De

punt-komma’s en haakjes scheiden de argumenten en functies van elkaar, Kijk goed

hoe de haakjes worden gebruikt.

Stap 1 Typ in cel B2 de naam van de eerste functie; VERT.ZOEKEN =VERT.ZOEKEN(

Stap 2 Typ de Zoekwaarde; $A2 =VERT.ZOEKEN($A2;

Stap 3 Typ de Tabelmatrix; $G$2:$K$11 =VERT.ZOEKEN($A2;$G$2:$K$11;

Stap 4 In plaats van het Kolomindex_getal komt nu de functie VERGELIJKEN Typ de naam van de tweede functie; VERGELIJKEN =VERT.ZOEKEN($A2;$G$2:$K$11;VERGELIJKEN(

Stap 5 Typ de Zoekwaarde; B$1 =VERT.ZOEKEN($A2;$G$2:$K$11;VERGELIJKEN(B$1;

Stap 6 Typ de ZoekMatrix; $G$1:$K$1 =VERT.ZOEKEN($A2;$G$2:$K$11;VERGELIJKEN(B$1;$G$1:$K$1;

Stap 7 Typ het Criteriumtype_getal; 0 en sluit de functie af met een haakje ); =VERT.ZOEKEN($A2;$G$2:$K$11;VERGELIJKEN(B$1;$G$1:$K$1;0);

Nu nog het laatste argument van de functie VERT.ZOEKEN.

Stap 8 Typ voor Benaderen; 0 en sluit de functie af met een haakje. =VERT.ZOEKEN($A2;$G$2:$K$11;VERGELIJKEN(B$1;$G$1:$K$1;0);0)

U kunt dit ook doen via het venster ‘Functieargumenten’.

Vul eerst de argumentvakken ‘Zoekwaarde’, ‘Tabelmatrix’ en ‘Benaderen’.

Klik in het argumentvak ‘Kolomindex_getal’.

Klik links in de formulebalk op het pijltje en klik op VERGELIJKEN.

Vul de argumenten van deze functie en bevestig.


Wat gebeurt er allemaal in deze functie? =VERT.ZOEKEN($A2;$G$2:$K$11;VERGELIJKEN(B$1;$G$1:$K$1;0);0)

Zoekwaarde $A2 De personeelscode

Tabelmatrix $G$2:$K$11 De matrix met de personeelsgegevens

Kolomindex_getal VERGELIJKEN Zoekwaarde B1 = Achternaam Zoeken_matrix $G$1:$K$1 Criteriumtype_getal 0 De eerste waarde die gelijk aan de zoekwaarde.

Het resultaat zal kolom 2 zijn. Benaderen 0

De functie VERGELIJKEN zoekt naar de positie binnen het bereik waarin de waarde

‘Achternaam’ voorkomt. In dit geval kolom 2.

Vergelijk dit nu eens met de functie VERT.ZOEKEN. =VERT.ZOEKEN($A2;$G$2:$K$11;2;0) =VERT.ZOEKEN($A2;$G$2:$K$11;VERGELIJKEN(B$1;$G$1:$K$1;0);0)

Als er nu een kolom wordt ingevoegd zal de functie VERT.ZOEKEN nog steeds de juiste gegevens vertonen. Oftewel een dynamische functie.

Bekijk welke delen van de functie absoluut, relatief of een combinatie zijn. Hierdoor

wordt het mogelijk dat de diverse functies kunnen worden doorgetrokken.

Nadelen van deze combinatie De combinatie met VERGELIJKEN is een duidelijke verbetering. Een nadeel is wel

dat de functie van links naar rechts werkt.

Het is nu mogelijk om kolommen tussen te voegen binnen de originele matrix, of toe

te voegen aan de rechterkant. Maar als er kolommen worden toegevoegd aan de

rechterkant van de matrix, wordt dat niet waargenomen.

In dat geval is het beter om te werken met de combinatie van de functies INDEX en VERGELIJKEN. Daarover meer in de volgende twee paragrafen.


Voorbeeld 2 In dit voorbeeld staat de factuur en de opzoektabel op verschillende werkbladen. In de gele cellen wordt de functie VERT.ZOEKEN gebruikt.

Maak het werkblad ‘Factuur’ actief.

De lijst met gegevens staat op het volgende werkblad.

In de zoekmatrix wordt een kolom tussengevoegd, ‘Kwaliteit’. Dit heeft grote gevolgen voor de gegevens in kolom D en E.

Als de functie was uitgebreid met de functie VERGELIJKEN, dan was dit nooit gebeurd.

Kijk goed hoe de diverse argumenten van de functies zijn opgebouwd. Het lijkt

ingewikkelder dan het is. Het lijkt ingewikkeld omdat de namen van de

werkbladen zijn opgenomen in de functie. Dat ontstaat als de celadressen worden

geselecteerd.


1.6. INDEX (INDEX)

De functie INDEX geeft een verwijzing naar een celadres dat een aantal rijen en

kolommen verwijderd is van de eerste cel van een bereik.

Let op: De functie heeft 2 varianten, gebruik voor de formules de matrix variant.

De functie INDEX heeft 3 argumenten; Matrix Verplicht Het bereik waarbinnen wordt gezocht. Rij_getal Verplicht Het aantal rijen vanaf het beginpunt van de matrix waarnaar

wordt verwezen. Kolom_getal Het aantal kolommen vanaf het beginpunt van de matrix

waarnaar wordt verwezen.

De voorbeelden vindt u in de werkmap ‘Index’.

Voorbeeld 1 Gebruik de functie INDEX om het rapportcijfer te vinden van Rapport 2 van Evert Vermeer.

De functie in cel C9 is; =INDEX(A1:F6;4;3) Matrix A1:F6 Het bereik waarbinnen moet worden gezocht. Rij_getal 4 4 regels naar beneden vanaf het beginpunt van de matrix. Kolom_getal 3 3 kolommen naar rechts vanaf het beginpunt van de matrix. Resultaat C4 Cijfer 8,3

Het is belangrijk om te weten dat de verwijzingen in Rij_getal en Kolom_getal gelden

voor de matrix. U werkt dus niet vanuit cel A1, maar uit de eerste cel in de matrix!

De functie INDEX is nogal beperkt, omdat de gegevens elke keer weer moeten

worden ingevoerd. Een samenwerking met een andere functie, bijvoorbeeld de

functie VERGELIJKEN is een oplossing.


1.7. INDEX en VERGELIJKEN (INDEX & MATCH)

De functie INDEX is nogal bewerkelijk. U moet immers altijd de gegevens invoeren

voor de matrix en de rijen kolomverwijzingen; = INDEX(A1:F6;4;3). Door de functie

INDEX te combineren met de functie VERGELIJKEN ontstaat een dynamische

functie.

Ter opfrissing

De functie VERGELIJKEN zoekt de positie van een waarde binnen een matrix. Kijk

zonodig nog eens in de paragraaf naar informatie over deze functie.

Om de argumenten te vinden uit het eerste voorbeeld, moet de functie INDEX

éénmaal en de functie VERGELIJKEN twee maal worden gebruikt.

Dit wordt een uitgebreide functie, dus ik ga hem eerst uitsplitsen en daarna

combineren.

Maak het werkblad ‘INDEX VERGELIJKEN’ actief.

De eerste keer dat VERGELIJKEN wordt gebruikt is om de rij met Evert Vermeer te vinden.

=VERGELIJKEN("Evert Vermeer";A2:A7;0)

In Nederlands; Zoek in het bereik A2:A7 het rijnummer (binnen de matrix) van de cel

met de tekst ‘Evert Vermeer’.

Uitkomst; 4 In het bereik A2:A7 staat de tekst Evert Vermeer in de 4e rij. De tweede keer dat VERGELIJKEN wordt gebruikt is om de kolom met Rapport 2 te vinden. =VERGELIJKEN("Rapport 2";A2:F2;0) In Nederlands; Zoek in het bereik A2:F2 naar het kolomnummer (binnen de matrix)

van de cel waar ‘Rapport 2’ in staat.

Uitkomst; 3 In het bereik A2:F2 staat Rapport 2 in de 3e kolom.


Nu de gecombineerde functie INDEX, VERGELIJKEN, VERGELIJKEN.

=INDEX(A2:A7; VERGELIJKEN("Evert Vermeer";A2:A7;0);

VERGELIJKEN("Rapport 2";A2:F2;0))

=INDEX (A2:A7; Rij_getal VERGELIJKEN("Evert Vermeer";A2:A7;0); (4) Kolom_getal VERGELIJKEN("Rapport 2";A2:F2;0)) (3)

Uitkomst 8,3

Had u alleen de INDEX-functie gebruikt, dan was deze functie zo ingevuld: =INDEX(A2:F7;4;3)

GEGEVENSVALIDATIE Nu is het invoeren van al die gegevens veel meer werk. Ga ervan uit dat een

dergelijke tabel vaak wordt gebruikt. Om de invoer te vereenvoudigen kunt u beter

gebruik maken van de mogelijkheden van gegevensvalidatie.

Open het werkblad ‘Gegevensvalidatie’.

In cel I2 en I3 zijn twee gegevensvalidatielijsten gemaakt die te openen zijn door op de pijlen rechts naast de cellen te klikken. De twee lijsten die hiervoor zijn gebruikt, staan verdekt opgesteld in het bereik AA2:AB6. De functie in C9 is verbonden met cel I2. De functie in C10 is een eenvoudige =I3 formule. De functie in C11 is verbonden met cel I2 en I3.

Gebruik de pijltjestoetsen van I2 en I3 om de gegevens in cel C9 en cel C10 aan

te passen.


Nog een voorbeeld.

Maak het werkblad ‘Index Vergelijken (2)’ actief.

In dit laatste voorbeeld wordt het bereik C2:C5 gebruikt als zoekkolom.

In cel B7 wordt een zoekterm ingevoerd. De combinatie van de functies INDEX en

VERGELIJKEN zoekt aan de linkerkant van de zoekkolom informatie op.

De functie in B8 is; =INDEX($A$2:$A$5;VERGELIJKEN($B$7;$C$2:$C$5;0))

In Nederlands; Zoek in het bereik C2:C5 naar de rij waarin de inhoud van cel B7

in voorkomt. Volg de rij naar links tot je in kolom A bent aangeland. Toon de

inhoud van deze cel. In dit geval is dat M654.

Cel C7 is gevuld via gegevensvalidatie.

Klik op de pijl naast de cel om de namenlijst te zien.

Een ander voordeel is dat u bij de functie INDEX een specifieke rij of kolom aangeeft, bijvoorbeeld kolom A, (A2:A5). Bij VERT.ZOEKEN wordt een heel bereik aangegeven. Dit maakt bij een kleine tabel met weinig gegevens en een paar zoekfuncties niets uit. Maar werkt u met een grote tabel met veel zoekfuncties, dan kan dit veel tijd schelen tijden het opzoekproces. GEGEVENSVALIDATIE In het vorige voorbeeld is gegevensvalidatie gebruikt. Even een opfrissing (of nieuwe

kennis). Gegevensvalidatie zorgt er voor dat de ingevoerde gegevens volledig en

juist zijn. Er zijn veel manieren van gegevensvalidatie. In dit geval wordt een lijst

gebruikt voor de validatie. Uit de lijst moet een keus worden gemaakt uit een aantal

vaste gegevens.

Er zijn twee grote voordelen aan deze manier van werken;

Het werkt sneller dan gegevens invoeren

De gegevens worden gegarandeerd volledig en correct zijn ingevoerd

Bij zoekfuncties vraagt Excel altijd om de juiste informatie. Bij onjuiste invoer, al is het maar een spatie, volgt een foutmelding of de informatie wordt niet gevonden.


Een validatielijst maken Typ in cel A20 de tekst ‘Meneer’.

Typ in cel A21 de tekst ‘Mevrouw’.

Maak cel D20 actief.

Maak het lint ‘Gegevens’ actief.

Klik de knop ‘Gegevensvalidatie’ aan.

Maak de tab ‘Instellingen’ actief.

Selecteer in het vak ‘Toestaan’ de optie ‘Lijst’.

Klik het vak ‘Bron’ aan.

Geef het bereik ‘A20:A21’ aan.

(Selecteer het bereik met de muis)

Bevestig met ‘OK’.

Excel maakt er automatisch een absoluut

celadres van.

Als cel D20 nu actief wordt gemaakt, zal er

een keuzepijl naast de cel verschijnen.

Maak cel D20 actief.

Klik op de keuzepijl.

In dit geval is de keus beperkt tot twee

mogelijkheden; ‘Meneer’ en ‘Mevrouw’.

Klik één van de keuzes aan en de tekst staat in

de cel.

Bij ingewikkelde codes of namen is deze methode

absoluut aan te bevelen.


1.8. VERSCHUIVING (OFFSET)

De functie VERSCHUIVING geeft een verwijzing naar een bereik dat een aantal rijen

en kolommen verwijderd is van een opgegeven verwijzingscel.

De functie heeft 5 argumenten;

VERW Verplicht De verwijzingscel waarop de verschuiving wordt gebaseerd. Rijen Verplicht Het aantal rijen vanaf de verwijzingscel. Kolommen Verplicht Het aantal kolommen vanaf de verwijzingscel. Hoogte Het aantal rijen dat het resultaat hoog moet zijn. Breedte Het aantal kolommen dat het resultaat breed moet zijn.

De voorbeelden vindt u in de werkmap ‘Verschuiving’.

Voorbeeld 1 De formule in B4 is; =VERSCHUIVING(A1;1;1)

VERW A1 De verwijzingscel. Rijen 1 1 regel naar beneden vanaf de verwijzingscel. Kolommen 1 1 kolom naar rechts vanaf de verwijzingscel.

Resultaat Cel B2 118.000

De formule in C4 is; =VERSCHUIVING(A1;1;2)

VERW A1 De verwijzingscel. Rijen 1 1 regel naar beneden vanaf de verwijzingscel. Kolommen 2 2 kolommen naar rechts vanaf de verwijzingscel.

Resultaat Cel C2 125.000


Voorbeeld 2 De formule in B6 is;

=SOM(VERSCHUIVING(A1;1;4;1))

SOM =SOM(Bereik) Bereik (VERSCHUIVING(A1;1;4;1)) VERW A1 De verwijzingscel. Rijen 1 1 regel naar beneden vanaf rij 1. Kolommen 1 1 kolom naar rechts vanaf kolom A. (B1) Hoogte 4 Een bereik van 4 rijen vanaf cel B1. Breedte 1 Een bereik van 1 kolom vanaf cel B1.

Resultaat =SOM(B2:B5)

Voorbeeld 3 In dit voorbeeld is een SOM-functie gebruikt met een dynamisch bereik dankzij de

functie VERSCHUIVING.

Het voordeel van een dynamische SOM-functie is dat als u een rij of kolom invoegt of verwijderd boven rij 8 of kolom D, de SOM-functie zich automatisch zal aanpassen. De formule in B8 is; =SOM(B2:(VERSCHUIVING(B8;-1;0)))

SOM =SOM(Bereik) Bereik B2:(VERSCHUIVING(B8;-1;0)) VERW B8 De verwijzingscel. Rijen -1 1 regel naar boven vanaf rij 8. Kolommen 0 0 kolommen naar rechts vanaf kolom B.

Resultaat =SOM(B2:B7)

Het beginpunt van het bereik staat al vast, B2. Het eindpunt van het bereik wordt gevonden door de functie VERSCHUIVING.


De formule in E2 is; =SOM(B2:(VERSCHUIVING(E2;0;-1)))

SOM =SOM(Bereik) Bereik (B2:(VERSCHUIVING(E2;0;-1))) VERW E2 De verwijzingscel. Rijen 0 0 regels naar beneden. Kolommen -1 1 kolom naar links vanaf kolom E.

Resultaat =SOM(B2:D2) Geen van de celadressen is absoluut, dus de functie kan worden doorgetrokken naar

beneden.

Ik kan me voorstellen dat u nu zegt, dat dit wel veel werk is voor zo’n eenvoudige

functie. Ga er vanuit dat deze functies worden opgeslagen en dat ze vaak zullen

worden gebruikt.

In het volgende hoofdstuk, als deze functies worden gebruikt bij het maken van de

grafieken, zal wel duidelijk worden hoe veel nut een dynamisch bereik kan hebben.


1.9. Dynamisch bereik met VERSCHUIVING & AANTAL

(OFFSET & COUNT)

In de vorige paragraaf over de verwijsfunctie VERSCHUIVING is al een voorbeeld

gegeven met een dynamisch bereik.

De formule in B8 is;

=SOM(B2:(VERSCHUIVING(B8;-1;0)))

Het voordeel van een dynamische SOM functie is dat als u een rij of kolom invoegt of verwijderd boven rij 8 of kolom D, de SOM-functie zich automatisch zal aanpassen. In het voorbeeld moet er dan wel een rij of kolom worden

tussengevoegd om nut te hebben van deze functie.

In deze paragraaf moet een bereik worden opgeteld waarbinnen zich

nog veel lege cellen bevinden. Er kan dan een dynamische SOM-

functie worden gemaakt met behulp van twee functies

VERSCHUIVING en AANTAL.

Het voorbeeld kunt u vinden in de werkmap ‘Dynamische bereiken’

op het werkblad ‘Verschuiving en aantal’.

In kolom E moet er een Som functie worden gebruikt om de omzet

van de maand juni op te tellen.

Een eenvoudige methode is dan; =SOM(B2:B13). De volgende dag moet de functie dan wel worden aangepast in=SOM(B2:B14) enz.

Een andere mogelijkheid is de hele maand al vast op te nemen in de SOM-functie; =SOM(B2:B26). Deze mogelijkheid kan allerlei foutmeldingen veroorzaken, dus zeker niet aan te

raden.

Een andere mogelijkheid is het inschakelen van de functie VERSCHUIVING. =SOM(VERSCHUIVING($B$2;0;0;25))

Het bereik van de SOM-functie wordt dan B2 tot de cel 25 cellen lager, B26. Dit is eigenlijk gelijk aan =SOM(B2:B26). Er is nog altijd de kans op foutmeldingen

ivm met al die lege cellen in het optelbereik.

Verder moet het aantal cellen worden geteld.


De functie AANTAL

De beste mogelijkheid om het aantal gevulde cellen met getallen te laten tellen is met

de functie AANTAL; =SOM(VERSCHUIVING($B$2;0;0;AANTAL($B$2:$B$26)))

In het vorige voorbeeld met VERSCHUIVING is het aantal 25 keer geteld. De functie AANTAL telt het aantal cellen gevuld met getallen en geeft als antwoord

12.

In de functie VERSCHUIVING wordt nu, dankzij de functie AANTAL, het aantal cellen

dat gevuld is met getallen dynamisch ingevuld;

=SOM(VERSCHUIVING($B$2;0;0;12))

De volgende dag zal dat dan =SOM(VERSCHUIVING($B$2;0;0;13)) zijn. Hiermee is een dynamisch bereik gemaakt waarbij lege cellen niet worden

opgenomen in het bereik.

Opslaan als naam

Formules en functies worden opgeslagen in de cellen waar ze in staan. Ze kunnen

ook worden opgeslagen als naam. In dit geval wordt het dynamische bereik, dat

wordt gevonden via de combinatie VERSCHUIVING en AANTAL, opgeslagen als

naam.

Selecteer cel E7.

Kopieer uit de formulebalk de functie zonder het SOM gedeelte en het laatste

haakje;

VERSCHUIVING($B$2;0;0;AANTAL($B$2:$B$26))

Maak het lint Formules actief.

Klik in het vak ‘Gedefinieerde namen’ op de knop

‘Naam definiëren’.

Geef het bereik de naam ‘jun’.

(ik heb de naam juni al gebruikt)

‘Typ een = in het vak ‘Verwijst naar:’ en plak de

functie erachter.

Sluit af met ‘OK’.

De naam gebruiken

Typ =SOM(jun) en bevestig.

Het bedrag 25.090 verschijnt.

Vul de kolom met een aantal getallen en bekijk welke functies zich aanpassen.


1.10. Dynamisch bereik met INDEX & AANTAL (INDEX & COUNT)

In de vorige paragraaf is gewerkt met een dynamisch bereik gemaakt met de functie

VERSCHUIVING. Het is ook mogelijk de functie INDEX te gebruiken in plaats van

VERSCHUIVING.

De functie INDEX is één van de weinige functies die op twee manieren kan worden gebruikt.

matrix;rij_getal;kolom_getal

verw:rij_getal;kolom_getal:bereik_getal

In dit geval is gebruik gemaakt van de matrix variant. In een aantal stappen wordt een dynamische functie gemaakt voor het bereik A11:G20. Dit kan uiteraard ook een veel groter bereik zijn.

Het voorbeeld staat in de werkmap ‘Dynamische bereiken’.

Maak het werkblad ‘INDEX en AANTAL’ actief.

Als eerste voorbeeld wordt er een standaard Som-functie gebruikt voor de

optelling van het bereik A12:E16; =SOM(A12:E16)

Resultaat; 151.820

Als tweede voorbeeld een Som-functie plus INDEX voor de optelling van het

bereik A12:E16.

Er wordt niet naar een specifieke cel verwezen dus we hoeven in de INDEX

alleen het bereik aan te geven; =SOM(INDEX($A$12:$E$16;;))

Resultaat; 151.820

Er mogen ook nullen worden ingevoerd als u dat gemakkelijker vindt;

=SOM(INDEX($A$12:$E$16;0;0))

De nullen staan voor het rijen kolomnummer.

In feite lijkt dit veel op de standaard Som-functie. Alleen wordt het bereik nu

bepaald door de INDEX-functie; INDEX($A$12:$E$16;0;0)


Als derde voorbeeld wordt de INDEX-functie gebruikt om de inhoud van een

specifieke cel te vinden; =INDEX($A$11:$A$20;5)

Resultaat; Product D

Er wordt gevraagd naar de inhoud van de 5e cel in het bereik A11:A20.

Als vierde voorbeeld wordt een dynamisch INDEX-functie gebruikt om de inhoud

te vinden van de laatste cel in een bepaalde kolom;

=INDEX($A$11:$A$20;AANTALARG($A$11:$A$20))

Resultaat; Product E

Er wordt gevraagd naar de inhoud van de laatste cel in het bereik A11:A20.

Het nummer van de laatste cel wordt gevonden door de functie AANTALARG.

De functie AANTALARG telt het aantal gevulde cellen in een bereik, 6 in dit geval.

Zonder AANTALARG was het =INDEX($A$11:$A$20;6) geworden.

Als vijfde voorbeeld wordt een 1 dimensionale dynamische INDEX-functie

gebruikt om de som te vinden in een bepaalde kolom;

=SOM($B$12:INDEX($B$12:$B$20;AANTAL($B$12:$B$20)))

Resultaat; 37.320

Er wordt gevraagd naar de som van een bereik.

Het startpunt van het bereik is B12.

Het eindpunt van het bereik is de laatste cel in het bereik B12:B20.

De functie INDEX zoekt in het bereik B12:B20.

De functie AANTAL telt het aantal gevulde cellen met getallen in een bereik,

5 in dit geval.

Als eenvoudige SOM-functie is dit =SOM(B12:B16)


Als zesde voorbeeld wordt een 2 dimensionale dynamische INDEX-functie

gebruikt om de som te vinden in een bepaald bereik.

In feite is deze functie gelijk aan de vorige, maar nu wordt de zoekactie 2 maal

uitgevoerd, naar beneden en naar rechts.

=SOM($B$12:INDEX($12:$20;AANTAL($B$12:$B$20);AANTALARG($12:$12)))

Resultaat; 151.820

Er wordt gevraagd naar de som van een gebied.

Het startpunt van het bereik is B12.

Het eindpunt van het bereik naar beneden is de laatste gevulde cel in het bereik

B12:B20.

De functie INDEX zoekt in het bereik B12:B20.

De functie AANTAL telt het aantal gevulde cellen met getallen in een bereik, 5 in

dit geval.

De functie AANTALARG (er komt een woord voor in het bereik) telt het aantal

gevulde cellen in het bereik 12:12, rij 12 dus, 5 in dit geval.

Het nut van deze dynamische functie

Als er een nieuw product wordt toegevoegd en een nieuwe maand, zullen deze

automatisch worden meegenomen in de SOM-functie.

De uitkomsten in de twee dynamische bereiken worden automatisch aangepast.

Als er een nieuw product bijkomt in een latere periode, juni, dan moet u wel alle

cellen in rij 18 vullen met getallen, nullen in dit geval, anders reageert de functie niet.


Opslaan als naam Ook deze combinatie kan worden opgeslagen onder een naam.

Kopieer de laatste functie zonder de Som-functie.

($B$12:INDEX($12:$20;AANTAL($B$12:$B$20);AANTALARG($12:$12)))

Maak het lint ‘ Formules’ actief.

Klik in het vak ‘Gedefinieerde namen’ op de knop ‘Naam definiëren’.

Geef het bereik de naam ‘omzetten’. (ik heb de naam omzet al gebruikt)

‘Typ een = in het vak ‘Verwijst naar:’ en plak de functie erachter.

Sluit af met ‘OK’.

De naam gebruiken

Typ in een willekeurige cel =SOM(omzetten) en bevestig.

Vul het bereik met een aantal getallen en bekijk hoe de resultaten van de diverse

functies zich (wel of niet) aanpassen.

Duizelig

U hebt nu een pagina of 30 met allerlei functies en combinaties van functies

bestudeerd. De eerste keer dat ik deze stof bestudeerde duizelde het me behoorlijk.

Als dit allemaal nieuw is, dan duizelt u het waarschijnlijk ook.

Kijk bij elke combinatie naar de interactie tussen de functies, welke argumenten bij

de diverse functies horen en wat de diverse functies als resultaat geven. Maak de

functies na en bekijk de opbouw zorgvuldig.

Maak uw eigen voorbeelden en probeer de functies uit. Oefenen, oefenen en nog

meer oefenen is de enige manier om dit onderwerp, gecombineerde of geneste

functies, onder te knie te krijgen.

Er zijn nog meer combinaties mogelijk. In de volgende hoofdstukken zullen die wel

eens worden gebruikt. Na al deze voorbeelden zult u die wel uiteen kunnen rafelen.

In de volgende hoofdstukken gaan we grafieken maken (en gebruik maken van al

deze dynamische functies).

1. Functiesuitgeverijvandebunt.nl/images/downloaden... · Hoofdstuk 2 – Maak een dashboard met...

Documents

Transcript of 1. Functiesuitgeverijvandebunt.nl/images/downloaden... · Hoofdstuk 2 – Maak een dashboard met...